Copyright updates

Copyright updates

[Daniel Jacobowitz]

[-- Attachment #1: Type: text/plain, Size: 1040 bytes --]

The FSF announced, at some point in the last two years, that it was OK
to automatically add the current year to every source file in the
project if any changes were made to the project during the year.
In fact, they even recommend it.

  http://www.gnu.org/prep/maintain/html_node/Copyright-Notices.html

This is very boring to do by hand.  So, after much head-smacking,
here is a script which does it for 99% of GDB.  The exceptions are
commented.

I've attached both the script and its output.  I'm not really looking
for comments on the script unless someone wants to rewrite it in LISP;
it's a modified copyright.el from Emacs CVS, plus a scary shell script.
LISP is absolutely not my strong point.

Does anyone object to the intention, the script, or the sample output? 
I've proofed it as well as I can, but the uncompressed diff is 600K.
It was definitely quicker than the time I've wasted in the past
updating copyright years by hand, even if I did waste most of this
evening getting it to work.

-- 
Daniel Jacobowitz
CodeSourcery

[-- Attachment #2: copyright-code.patch --]
[-- Type: text/x-diff, Size: 11633 bytes --]

--- /dev/null	2007-01-02 16:56:32.718585262 -0500
+++ gdb/copyright.el	2007-01-03 19:56:53.000000000 -0500
@@ -0,0 +1,250 @@
+;;; copyright.el --- update the copyright notice in current buffer
+
+;; From emacs CVS, 2006-01-03, with local changes:
+;; Replaced ?\s with "?\ " which seems to be good enough for emacs
+;; 21.4.  Made it re-fill after adding a year.
+
+;; Copyright (C) 1991, 1992, 1993, 1994, 1995, 1998, 2001, 2002, 2003,
+;;   2004, 2005, 2006 Free Software Foundation, Inc.
+
+;; Author: Daniel Pfeiffer <occitan@esperanto.org>
+;; Keywords: maint, tools
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation; either version 2, or (at your option)
+;; any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs; see the file COPYING.  If not, write to the
+;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
+;; Boston, MA 02110-1301, USA.
+
+;;; Commentary:
+
+;; Allows updating the copyright year and above mentioned GPL version manually
+;; or when saving a file.
+;; Do (add-hook 'before-save-hook 'copyright-update), or use
+;; M-x customize-variable RET before-save-hook RET.
+
+;;; Code:
+
+(defgroup copyright nil
+  "Update the copyright notice in current buffer."
+  :group 'tools)
+
+(defcustom copyright-limit 2000
+  "*Don't try to update copyright beyond this position unless interactive.
+A value of nil means to search whole buffer."
+  :group 'copyright
+  :type '(choice (integer :tag "Limit")
+		 (const :tag "No limit")))
+
+;; The character classes have the Latin-1 version and the Latin-9
+;; version, which is probably enough.
+(defcustom copyright-regexp
+ "\\([©Ž©]\\|@copyright{}\\|[Cc]opyright\\s *:?\\s *\\(?:(C)\\)?\
+\\|[Cc]opyright\\s *:?\\s *[©Ž©]\\)\
+\\s *\\([1-9]\\([-0-9, ';/*%#\n\t]\\|\\s<\\|\\s>\\)*[0-9]+\\)"
+  "*What your copyright notice looks like.
+The second \\( \\) construct must match the years."
+  :group 'copyright
+  :type 'regexp)
+
+(defcustom copyright-years-regexp
+ "\\(\\s *\\)\\([1-9]\\([-0-9, ';/*%#\n\t]\\|\\s<\\|\\s>\\)*[0-9]+\\)"
+  "*Match additional copyright notice years.
+The second \\( \\) construct must match the years."
+  :group 'copyright
+  :type 'regexp)
+
+
+(defcustom copyright-query 'function
+  "*If non-nil, ask user before changing copyright.
+When this is `function', only ask when called non-interactively."
+  :group 'copyright
+  :type '(choice (const :tag "Do not ask")
+		 (const :tag "Ask unless interactive" function)
+		 (other :tag "Ask" t)))
+
+
+;; when modifying this, also modify the comment generated by autoinsert.el
+(defconst copyright-current-gpl-version "2"
+  "String representing the current version of the GPL or nil.")
+
+(defvar copyright-update t)
+
+;; This is a defvar rather than a defconst, because the year can
+;; change during the Emacs session.
+(defvar copyright-current-year (substring (current-time-string) -4)
+  "String representing the current year.")
+
+(defun copyright-update-year (replace noquery)
+  (when (re-search-forward copyright-regexp (+ (point) copyright-limit) t)
+    ;; If the years are continued onto multiple lined
+    ;; that are marked as comments, skip to the end of the years anyway.
+    (while (save-excursion
+	     (and (eq (following-char) ?,)
+		  (progn (forward-char 1) t)
+		  (progn (skip-chars-forward " \t") (eolp))
+		  comment-start-skip
+		  (save-match-data
+		    (forward-line 1)
+		    (and (looking-at comment-start-skip)
+			 (goto-char (match-end 0))))
+		  (save-match-data
+		    (looking-at copyright-years-regexp))))
+      (forward-line 1)
+      (re-search-forward comment-start-skip)
+      (re-search-forward copyright-years-regexp))
+
+    ;; Note that `current-time-string' isn't locale-sensitive.
+    (setq copyright-current-year (substring (current-time-string) -4))
+    (unless (string= (buffer-substring (- (match-end 2) 2) (match-end 2))
+		     (substring copyright-current-year -2))
+      (if (or noquery
+	      (y-or-n-p (if replace
+			    (concat "Replace copyright year(s) by "
+				    copyright-current-year "? ")
+			  (concat "Add " copyright-current-year
+				  " to copyright? "))))
+	  (if replace
+	      (replace-match copyright-current-year t t nil 2)
+	    (let ((size (save-excursion (skip-chars-backward "0-9"))))
+	      (if (and (eq (% (- (string-to-number copyright-current-year)
+				 (string-to-number (buffer-substring
+						    (+ (point) size)
+						    (point))))
+			      100)
+			   1)
+		       (or (eq (char-after (+ (point) size -1)) ?-)
+			   (eq (char-after (+ (point) size -2)) ?-)))
+		  ;; This is a range so just replace the end part.
+		  (delete-char size)
+		;; Insert a comma with the preferred number of spaces.
+		(insert
+		 (save-excursion
+		   (if (re-search-backward "[0-9]\\( *, *\\)[0-9]"
+					   (line-beginning-position) t)
+		       (match-string 1)
+		     ", ")))
+		;; If people use the '91 '92 '93 scheme, do that as well.
+		(if (eq (char-after (+ (point) size -3)) ?')
+		    (insert ?')))
+	      ;; Finally insert the new year.
+	      (insert (substring copyright-current-year size))
+	      ;; drow local
+	      (let ((par-end (save-excursion (end-of-paragraph-text) (point))))
+		(let ((inc-end (save-excursion
+				 (re-search-forward "Inc\." par-end t))))
+		  (let ((limit (if inc-end inc-end par-end)))
+		    (fill-region-as-paragraph (line-beginning-position) limit))))
+	      ))))))
+
+;;;###autoload
+(defun copyright-update (&optional arg interactivep)
+  "Update copyright notice at beginning of buffer to indicate the current year.
+With prefix ARG, replace the years in the notice rather than adding
+the current year after them.  If necessary, and
+`copyright-current-gpl-version' is set, any copying permissions
+following the copyright are updated as well.
+If non-nil, INTERACTIVEP tells the function to behave as when it's called
+interactively."
+  (interactive "*P\nd")
+  (when (or copyright-update interactivep)
+    (let ((noquery (or (not copyright-query)
+		       (and (eq copyright-query 'function) interactivep))))
+      (save-excursion
+	(save-restriction
+	  (widen)
+	  (goto-char (point-min))
+	  (copyright-update-year arg noquery)
+	  (goto-char (point-min))
+	  (and copyright-current-gpl-version
+	       ;; match the GPL version comment in .el files, including the
+	       ;; bilingual Esperanto one in two-column, and in texinfo.tex
+	       (re-search-forward "\\(the Free Software Foundation;\
+ either \\|; a\\^u eldono \\([0-9]+\\)a, ? a\\^u (la\\^u via	 \\)\
+version \\([0-9]+\\), or (at"
+				  (+ (point) copyright-limit) t)
+	       (not (string= (match-string 3) copyright-current-gpl-version))
+	       (or noquery
+		   (y-or-n-p (concat "Replace GPL version by "
+				     copyright-current-gpl-version "? ")))
+	       (progn
+		 (if (match-end 2)
+		     ;; Esperanto bilingual comment in two-column.el
+		     (replace-match copyright-current-gpl-version t t nil 2))
+		 (replace-match copyright-current-gpl-version t t nil 3))))
+	(set (make-local-variable 'copyright-update) nil)))
+    ;; If a write-file-hook returns non-nil, the file is presumed to be written.
+    nil))
+
+
+;;;###autoload
+(defun copyright-fix-years ()
+  "Convert 2 digit years to 4 digit years.
+Uses heuristic: year >= 50 means 19xx, < 50 means 20xx."
+  (interactive)
+  (widen)
+  (goto-char (point-min))
+  (if (re-search-forward copyright-regexp (+ (point) copyright-limit) t)
+      (let ((s (match-beginning 2))
+	    (e (copy-marker (1+ (match-end 2))))
+	    (p (make-marker))
+	    last)
+	(goto-char s)
+	(while (re-search-forward "[0-9]+" e t)
+	  (set-marker p (point))
+	  (goto-char (match-beginning 0))
+	  (let ((sep (char-before))
+		(year (string-to-number (match-string 0))))
+	    (when (and sep
+		       (/= (char-syntax sep) ?\ )
+		       (/= sep ?-))
+	      (insert " "))
+	    (when (< year 100)
+	      (insert (if (>= year 50) "19" "20"))))
+	  (goto-char p)
+	  (setq last p))
+	(when last
+	  (goto-char last)
+	  ;; Don't mess up whitespace after the years.
+	  (skip-chars-backward " \t")
+	  (save-restriction
+	    (narrow-to-region (point-min) (point))
+	    (let ((fill-prefix "     "))
+	      (fill-region s last))))
+	(set-marker e nil)
+	(set-marker p nil)
+	(copyright-update nil t))
+    (message "No copyright message")))
+
+;;;###autoload
+(define-skeleton copyright
+  "Insert a copyright by $ORGANIZATION notice at cursor."
+  "Company: "
+  comment-start
+  "Copyright (C) " `(substring (current-time-string) -4) " by "
+  (or (getenv "ORGANIZATION")
+      str)
+  '(if (> (point) (+ (point-min) copyright-limit))
+       (message "Copyright extends beyond `copyright-limit' and won't be updated automatically."))
+  comment-end \n)
+
+(provide 'copyright)
+
+;; For the copyright sign:
+;; Local Variables:
+;; coding: emacs-mule
+;; End:
+
+;;; arch-tag: b4991afb-b6b1-4590-bebe-e076d9d4aee8
+;;; copyright.el ends here
--- /dev/null	2007-01-02 16:56:32.718585262 -0500
+++ gdb/copyright.sh	2007-01-03 20:04:44.000000000 -0500
@@ -0,0 +1,84 @@
+# Automatically update copyright for GDB, the GNU debugger.
+#
+# Copyright (C) 2007
+# Free Software Foundation, Inc.
+#
+# This file is part of GDB.
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, Inc., 51 Franklin Street, Fifth Floor,
+# Boston, MA 02110-1301, USA.
+
+# Usage: cd src/gdb && sh ./copyright.sh
+# After running, update those files mentioned in $byhand by hand.
+# Always review the output of this script before committing it!
+
+# Emacs 21.4 does not wrap Lex input as C, Autoconf input without
+# duplicating DNL, texinfo without duplicating @c, tex without
+# duplicating %, *.defs as C, man.  So these need to be done
+# by hand.
+byhand="
+*.l
+*.ac
+*.texi
+*.texinfo
+*.tex
+*.defs
+*.1
+"
+
+# Files which should not be modified, either because they are
+# generated, non-FSF, or otherwise special (e.g. license text).
+prunes="
+COPYING
+CVS
+configure
+gdbarch.c
+gdbarch.h
+fdl.texi
+gpl.texi
+gdbtk
+gdb.gdbtk
+osf-share
+aclocal.m4
+"
+
+cat > copytmp.el <<EOF
+(setq copyright-query nil)
+(setq vc-cvs-stay-local nil)
+(load-file "copyright.el")
+EOF
+
+for f in $prunes $byhand; do
+  prune_opts="$prune_opts -name $f -prune -o"
+done
+
+for f in $(find . $prune_opts -type f -print); do
+  cat >> copytmp.el <<EOF
+(switch-to-buffer (find-file "$f"))
+(setq backup-inhibited t)
+(setq write-file-hooks '())
+(copyright-update)
+(save-buffer)
+(kill-buffer (buffer-name))
+EOF
+done
+
+cat >> copytmp.el <<EOF
+(kill-emacs)
+(delete-file "copytmp.el")
+EOF
+
+exec emacs -q -l ./copytmp.el
+

[-- Attachment #3: copyright-updates.diff.gz --]
[-- Type: application/octet-stream, Size: 54694 bytes --]

Re: Copyright updates

[Eli Zaretskii]

> Date: Wed, 3 Jan 2007 20:16:36 -0500
> From: Daniel Jacobowitz <drow@false.org>
> 
> Does anyone object to the intention, the script, or the sample output? 
> I've proofed it as well as I can, but the uncompressed diff is 600K.
> It was definitely quicker than the time I've wasted in the past
> updating copyright years by hand, even if I did waste most of this
> evening getting it to work.
> 
> -- 
> Daniel Jacobowitz
> CodeSourcery
> 
> --G4iJoqBmSsgzjUCe
> Content-Type: text/x-diff; charset=iso-8859-1
> Content-Disposition: attachment; filename="copyright-code.patch"
> Content-Transfer-Encoding: 8bit
> 
> --- /dev/null	2007-01-02 16:56:32.718585262 -0500
> +++ gdb/copyright.el	2007-01-03 19:56:53.000000000 -0500

Why are we including a package in GDB that is part of Emacs, and
why modify it while doing that?  Can't we simply tell people ``use
copyright.el from Emacs''?

Re: Copyright updates

[Daniel Jacobowitz]

On Thu, Jan 04, 2007 at 06:32:06AM +0200, Eli Zaretskii wrote:
> Why are we including a package in GDB that is part of Emacs, and
> why modify it while doing that?  Can't we simply tell people ``use
> copyright.el from Emacs''?

Pragmatics: Because I needed to modify it to get the results I posted.
Otherwise, it has no respect for margins - it would just push things
further and further out to the right.  And because the version in the
last release of emacs was too old to use, and the version in emacs CVS
needs to be modified to work with my system's installed emacs.

I'm happy to just check in the year updates and hold on to the script
if that's controversial (which I realize it may be, given the FSF
policy on importing modified files).  It's probably possible to rewrite
my changes to use an installed CVS emacs and its copyright.el plus a
little extra goo, but I can't do it; my Lisp is too weak and I've spent
all the time on automating this that I can afford to.  Same goes for
trying to get the copy in emacs CVS improved.  Sorry :-(  Another six
hours in the day...

-- 
Daniel Jacobowitz
CodeSourcery

Re: Copyright updates

[Eli Zaretskii]

> Date: Wed, 3 Jan 2007 23:41:49 -0500
> From: Daniel Jacobowitz <drow@false.org>
> Cc: gdb@sourceware.org
> 
> On Thu, Jan 04, 2007 at 06:32:06AM +0200, Eli Zaretskii wrote:
> > Why are we including a package in GDB that is part of Emacs, and
> > why modify it while doing that?  Can't we simply tell people ``use
> > copyright.el from Emacs''?
> 
> Pragmatics: Because I needed to modify it to get the results I posted.
> Otherwise, it has no respect for margins - it would just push things
> further and further out to the right.  And because the version in the
> last release of emacs was too old to use, and the version in emacs CVS
> needs to be modified to work with my system's installed emacs.

The best way to solve this is to modify the Emacs version to avoid the
problem with margins.  I'd prefer if we didn't maintain a tailored
version in the GDB tree.

> It's probably possible to rewrite my changes to use an installed CVS
> emacs and its copyright.el plus a little extra goo, but I can't do
> it; my Lisp is too weak and I've spent all the time on automating
> this that I can afford to.

I will have a look and try to fix the official version in a few days.

Re: Copyright updates

[Daniel Jacobowitz]

On Fri, Jan 05, 2007 at 12:02:56AM +0200, Eli Zaretskii wrote:
> The best way to solve this is to modify the Emacs version to avoid the
> problem with margins.  I'd prefer if we didn't maintain a tailored
> version in the GDB tree.
> 
> > It's probably possible to rewrite my changes to use an installed CVS
> > emacs and its copyright.el plus a little extra goo, but I can't do
> > it; my Lisp is too weak and I've spent all the time on automating
> > this that I can afford to.
> 
> I will have a look and try to fix the official version in a few days.

Fine by me - thank you!

Would you like me to hold off on updating copyright years until we have
some official software to do it with, or just go ahead with what I
have?  I don't think it makes much difference how I did it; I'd
normally do it by hand.

-- 
Daniel Jacobowitz
CodeSourcery

Re: Copyright updates

[Eli Zaretskii]

> Date: Thu, 4 Jan 2007 17:09:06 -0500
> From: Daniel Jacobowitz <drow@false.org>
> Cc: gdb@sourceware.org
> 
> Would you like me to hold off on updating copyright years until we have
> some official software to do it with, or just go ahead with what I
> have?

There's no need to wait, fixing copyright.el is a separate, almost
unrelated, job.

Actually, given that we produce a snapshot every day, it is quite
urgent to commit your update of copyright years ASAP.

Re: Copyright updates

[Eli Zaretskii]

> Date: Wed, 3 Jan 2007 23:41:49 -0500
> From: Daniel Jacobowitz <drow@false.org>
> Cc: gdb@sourceware.org
> 
> On Thu, Jan 04, 2007 at 06:32:06AM +0200, Eli Zaretskii wrote:
> > Why are we including a package in GDB that is part of Emacs, and
> > why modify it while doing that?  Can't we simply tell people ``use
> > copyright.el from Emacs''?
> 
> Pragmatics: Because I needed to modify it to get the results I posted.
> Otherwise, it has no respect for margins - it would just push things
> further and further out to the right.

I suggest below a modification in your script that should take care of
filling the copyright years, please see if it solves the problem.

I promised to see if copyright.el can be fixed to fill the results
after adding the missing year, but I cannot see any good way of doing
that, since copyright.el does not only support FSF copyrights, but is
supposed to honor copyrights of other organizations.  So I think it's
best to refill in your script, which is what I've done below.

> And because the version in the last release of emacs was too old to
> use

I tested the change I suggest below with Emacs 21.4.  It works, but I
don't recommend using copyright.el from v21.x, as it has bugs when the
copyright years span more than one line.  For example, it goofs with
ada-typeprint.c: it adds 2007 after 2000, not after 2004.  Perhaps we
should add a comment about this in your script.

> +cat > copytmp.el <<EOF
> +(setq copyright-query nil)
> +(setq vc-cvs-stay-local nil)
> +(load-file "copyright.el")
> +EOF
> +
> +for f in $prunes $byhand; do
> +  prune_opts="$prune_opts -name $f -prune -o"
> +done
> +
> +for f in $(find . $prune_opts -type f -print); do
> +  cat >> copytmp.el <<EOF
> +(switch-to-buffer (find-file "$f"))
> +(setq backup-inhibited t)
> +(setq write-file-hooks '())
> +(copyright-update)          <<<<<<<<<<
> +(save-buffer)
> +(kill-buffer (buffer-name))
> +EOF
> +done
> +
> +cat >> copytmp.el <<EOF
> +(kill-emacs)
> +(delete-file "copytmp.el")
> +EOF

I suggest to modify this slightly: instead of the single line marked
with <<<<<<<<<<, use the following lines (indentation is not
important, it's here for readability):

(widen)
(goto-char (point-min))
(if (re-search-forward copyright-regexp (+ (point) copyright-limit) t)
    (progn
      (setq copyright-update t
	    copyright-query nil
	    fill-column 78
	    start (point-marker)
	    end (progn
		  (re-search-forward
		   "Free[ \t\n]+Software[ \t\n]+Foundation,[ \t\n]+Inc\."
		   (+ (point) copyright-limit) t)
		  (point-marker))
	    fsf-start (copy-marker (match-beginning 0)))
      (replace-match "Free_Software_Foundation,_Inc." t t)
      (copyright-update)
      (fill-region-as-paragraph start end)
      (replace-string "_" " " nil fsf-start end))
  (message "WARNING: No copyright message found in $f"))

In case you wonder, the "Free_Software_Foundation,_Inc." gork is to
avoid breaking up "Free Software Foundation, Inc." during filling, but
at the same time to account for its length.

Re: Copyright updates

[Eli Zaretskii]

> Date: Sat, 06 Jan 2007 16:05:16 +0200
> From: Eli Zaretskii <eliz@gnu.org>
> CC: gdb@sourceware.org

One other thing: I suggest to modify this line:

  +exec emacs -q -l ./copytmp.el

to pass the --no-site-file switch to Emacs, in addition to -q, as some
installations have site-init.el files that are better taken out of the
equation.