[PATCHv2 1/3] gdb/testsuite: Detect and warn if paths are used in test names

Andrew Burgess
2020-04-27T22:01:52Z

A new library is introduced that hooks into the core of Dejagnu and
detects when a test's name includes either the source or build paths.
If any offending test names are detected then Dejagnu will print a
new result type, '# of paths in test names'. Users should treat this
result type just like other bad results types, and aim not to increase
this number.

Currently for a local run on my machine, I don't see any offending
test names, but it is possible that different targets, or different
configurations, might currently be breaking the no paths rule.

In order to get this working I have needed to wrap two core Dejagnu
functions, log_summary, and reset_vars. Relying on core functions
that are not part of any API is always going to be risky, given the
relatively slow rate of Dejagnu change this is probably OK for now,
and we can possibly upstream some changes to Dejagnu that would allow
this functionality to be supported in a more official way later on.

Currently if the tests are run in parallel mode the new result type is
not merged into the combined summary file so users will need to run in
non-parallel mode to check this result. A later commit will fix this.

gdb/testsuite/ChangeLog:

* lib/gdb.exp: Include check-test-names.exp library.
* lib/check-test-names.exp: New file.
---
gdb/testsuite/ChangeLog | 5 ++
gdb/testsuite/lib/check-test-names.exp | 115 +++++++++++++++++++++++++
gdb/testsuite/lib/gdb.exp | 1 +
3 files changed, 121 insertions(+)
create mode 100644 gdb/testsuite/lib/check-test-names.exp

diff --git a/gdb/testsuite/lib/check-test-names.exp b/gdb/testsuite/lib/check-test-names.exp
new file mode 100644
index 00000000000..702dc6ef406
--- /dev/null
+++ b/gdb/testsuite/lib/check-test-names.exp
@@ -0,0 +1,115 @@
+# Copyright 2020 Free Software Foundation, Inc.
+
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 3 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program. If not, see <http://www.gnu.org/licenses/>.
+
+# This library provides some protection against the introduction of
+# tests that include either the source of build paths in the test
+# name. When a test includes the path in its test name it is harder
+# to compare results between two runs of GDB from different trees.
+
+namespace eval ::CheckTestNames {
+ # An associative array of counts of tests that include a path in their
+ # test name. There are two counts, 'count', which counts occurrences
+ # within a single variant run, and 'total', which counts across all
+ # variants.
+ variable counts
+ array set counts {}
+ foreach nm {paths} {
+ set counts($nm,count) 0
+ set counts($nm,total) 0
+ }
+
+ # Increment the count, and total count for TYPE.
+ proc inc_count { type } {
+ variable counts
+
+ incr counts($type,count)
+ incr counts($type,total)
+ }
+
+ # Check if MESSAGE contains either the source path or the build path.
+ # This will result in test names that can't easily be compared between
+ # different runs of GDB.
+ #
+ # Any offending paths in message cause PATHS_IN_TEST_NAMES to be
+ # incremented.
+ proc check { message } {
+ global srcdir objdir
+
+ foreach path [list $srcdir $objdir] {
+ if { [ string first $path $message ] >= 0 } {
+ # Count each test just once.
+ inc_count paths
+ return
+ }
+ }
+ }
+
+ # If COUNT is greater than zero, disply PREFIX followed by COUNT.
+ proc maybe_show_count { prefix count } {
+ if { $count > 0 } {
+ clone_output "$prefix$count"
+ }
+ }
+
+ # Rename Dejagnu's log_summary procedure, and create do_log_summary to
+ # replace it. We arrange to have do_log_summary called later.
+ rename ::log_summary log_summary
+ proc do_log_summary { args } {
+ variable counts
+
+ # If ARGS is the empty list then we don't want to pass a single
+ # empty string as a parameter here.
+ eval "CheckTestNames::log_summary $args"
+
+ if { [llength $args] == 0 } {
+ set which "count"
+ } else {
+ set which [lindex $args 0]
+ }
+
+ maybe_show_count "# of paths in test names\t" \
+ $counts(paths,$which)
+ }
+
+ # Rename Dejagnu's reset_vars procedure, and create do_reset_vars to
+ # replace it. We arrange to have do_reset_vars called later.
+ rename ::reset_vars reset_vars
+ proc do_reset_vars {} {
+ variable counts
+
+ CheckTestNames::reset_vars
+
+ foreach nm {paths} {
+ set counts($nm,count) 0
+ }
+ }
+}
+
+# Arrange for Dejagnu to call CheckTestNames::check for each test result.
+foreach nm {pass fail xfail kfail xpass kpass unresolved untested \
+ unsupported} {
+ set local_record_procs($nm) "CheckTestNames::check"
+}
+
+# Create new global log_summary to replace Dejagnu's.
+proc log_summary { args } {
+ eval "CheckTestNames::do_log_summary $args"
+}
+
+# Create new global reset_vars to replace Dejagnu's.
+proc reset_vars {} {
+ eval "CheckTestNames::do_reset_vars"
+}
+
diff --git a/gdb/testsuite/lib/gdb.exp b/gdb/testsuite/lib/gdb.exp
index 2208f3a1a9b..aa95f6da933 100644
--- a/gdb/testsuite/lib/gdb.exp
+++ b/gdb/testsuite/lib/gdb.exp
@@ -29,6 +29,7 @@ load_lib libgloss.exp
load_lib cache.exp
load_lib gdb-utils.exp
load_lib memory.exp
+load_lib check-test-names.exp

global GDB

--
2.25.3