Re: [patch] Try to use python-config to get python include and lib parameters.

Doug Evans
2010-05-21T05:29:18Z

[-- Attachment #1: Type: text/plain, Size: 1077 bytes --]

On Thu, May 20, 2010 at 4:04 PM, Doug Evans <dje@google.com> wrote:
> Hi.
>
> Building with a private copy of python, or even the system copy,
> sometimes requires linking with extra libraries.
> These libraries are listed with `python-config --ldflags'.
> [or --libs, but --ldflags also includes any needed -L's]
>
> I will check this in in a few days if there are no objections.
>
> 2010-05-20  Doug Evans  <dje@google.com>
>
>        * configure.ac: Try to use python-config to get python include and lib
>        parameters.
>        * configure: Regenerate.

python-config is a python script so it won't work when build != host.

2010-05-20 Doug Evans <dje@google.com>

* configure.ac: For non-canadian-cross builds (build == host),
try to use python-config to get python include and lib parameters.
* configure: Regenerate.

Tested with
build=host=target=amd64-linux [with/without python]
build=host=amd64-linux target=arm-eabi [with/without python]
build=amd64-linux host=i386-linux target=arm-eabi [without python]

[-- Attachment #2: gdb-100520-python-config-2.patch.txt --]
[-- Type: text/plain, Size: 7066 bytes --]

2010-05-20 Doug Evans <dje@google.com>

* configure.ac: For non-canadian-cross builds (build == host),
try to use python-config to get python include and lib parameters.
* configure: Regenerate.

Index: configure.ac
===================================================================
RCS file: /cvs/src/src/gdb/configure.ac,v
retrieving revision 1.117
diff -u -p -r1.117 configure.ac
--- configure.ac 23 Apr 2010 18:07:26 -0000 1.117
+++ configure.ac 21 May 2010 05:12:25 -0000
@@ -589,22 +589,31 @@ else
fi

dnl Utility to simplify finding libpython.
+dnl $1 = pythonX.Y
+dnl $2 = the shell variable to assign the result to
+dnl If libpython is found we store $version here.
+dnl $3 = additional flags to add to CPPFLAGS
+dnl $4 = additional flags to add to LIBS
+
AC_DEFUN([AC_TRY_LIBPYTHON],
[
version=$1
define([have_libpython_var],$2)
- define([VERSION],[translit([$1],[abcdefghijklmnopqrstuvwxyz./-],
- [ABCDEFGHIJKLMNOPQRSTUVWXYZ___])])
- [HAVE_LIB]VERSION=no
+ new_CPPFLAGS=$3
+ new_LIBS=$4
AC_MSG_CHECKING([for ${version}])
+ save_CPPFLAGS=$CPPFLAGS
save_LIBS=$LIBS
- LIBS="$LIBS -l${version}"
+ CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
+ LIBS="$LIBS $new_LIBS"
+ found_usable_python=no
AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "${version}/Python.h"]],
[[Py_Initialize ();]]),
- [[HAVE_LIB]VERSION=yes
- have_libpython_var=yes],
- [LIBS=$save_LIBS])
- AC_MSG_RESULT([$[HAVE_LIB]VERSION])
+ [have_libpython_var=${version}
+ found_usable_python=yes],
+ [CPPFLAGS=$save_CPPFLAGS
+ LIBS=$save_LIBS])
+ AC_MSG_RESULT([${found_usable_python}])
])

AC_ARG_WITH(python,
@@ -617,45 +626,96 @@ if test "${with_python}" = no; then
AC_MSG_WARN([python support disabled; some features may be unavailable.])
have_libpython=no
else
+ have_python_config=no
case "${with_python}" in
yes | auto)
- # Leave as empty, use defaults.
- python_includes=
- python_libs=
+ # We can't use python-config in the non-native case, it's a python script.
+ if test ${build} = ${host}; then
+ AC_PATH_PROG(python_config_path, python-config, missing)
+ if test "${python_config_path}" = missing; then
+ # Perhaps this should be an error, but 7.0 and 7.1 shipped without
+ # checking for python-config so in the interests of not breaking
+ # anything, we follow their behaviour here.
+ python_includes=
+ python_libs=
+ else
+ python_includes=`${python_config_path} --includes`
+ python_libs=`${python_config_path} --ldflags`
+ have_python_config=yes
+ fi
+ else
+ python_includes=
+ python_libs=
+ fi
;;
/*)
- python_includes="-I${with_python}/include"
- python_libs="-L${with_python}/lib"
+ if test ${build} = ${host}; then
+ AC_PATH_PROG(python_config_path, python-config, missing,
+ [PATH = ${with_python}/bin])
+ if test "${python_config_path}" = missing; then
+ # If an explicit path was provided, and we can't find python-config
+ # at that location, flag an error.
+ AC_ERROR(python-config missing from ${with_python}/bin)
+ fi
+ python_includes=`${python_config_path} --includes`
+ python_libs=`${python_config_path} --ldflags`
+ have_python_config=yes
+ else
+ python_includes="-I${with_python}/include"
+ python_libs="-L${with_python}/lib"
+ fi
;;
*)
AC_ERROR(invalid value for --with-python)
;;
esac

- save_CPPFLAGS=$CPPFLAGS
- CPPFLAGS="$CPPFLAGS ${python_includes}"
- save_LIBS=$LIBS
- LIBS="$LIBS ${python_libs}"
+ # Having "/pythonX.Y" in the include path is awkward.
+ # All those python headers get bubbled up to the top inviting lots
+ # of random collisions. GDB originally didn't use python-config to
+ # find the compilation parameters and includes "pythonX.Y/" in the
+ # path of the, umm, include file. So strip away this part of the
+ # output of python-config --includes.
+ python_includes=`echo "${python_includes} " \
+ | sed -e 's,/python[[0-9]]*[[.]][[0-9]]* , ,g'`
+
+ # If we have python-config, only try the configuration it provides.
+ # Otherwise fallback on the old way of trying different versions of
+ # python in turn.
+
have_libpython=no
- if test "${have_libpython}" = no; then
- AC_TRY_LIBPYTHON(python2.6, have_libpython)
- if test "${HAVE_LIBPYTHON2_6}" = yes; then
- AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
+ if test "${have_python_config}" = yes; then
+ python_version=`echo " ${python_libs} " \
+ | sed -e 's,^.* -l\(python[[0-9]]*[[.]][[0-9]]*\) .*$,\1,'`
+ if test "${python_version}" != ""; then
+ AC_TRY_LIBPYTHON(${python_version}, have_libpython,
+ ${python_includes}, ${python_libs})
+ else
+ AC_MSG_ERROR([unable to determine python version from ${python_libs}])
fi
- fi
- if test ${have_libpython} = no; then
- AC_TRY_LIBPYTHON(python2.5, have_libpython)
- if test "${HAVE_LIBPYTHON2_5}" = yes; then
- AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
+ else
+ if test "${have_libpython}" = no; then
+ AC_TRY_LIBPYTHON(python2.6, have_libpython,
+ ${python_includes}, "${python_libs} -lpython2.6")
fi
- fi
- if test ${have_libpython} = no; then
- AC_TRY_LIBPYTHON(python2.4, have_libpython)
- if test "${HAVE_LIBPYTHON2_4}" = yes; then
- AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
+ if test ${have_libpython} = no; then
+ AC_TRY_LIBPYTHON(python2.5, have_libpython,
+ ${python_includes}, "${python_libs} -lpython2.5")
fi
+ if test ${have_libpython} = no; then
+ AC_TRY_LIBPYTHON(python2.4, have_libpython,
+ ${python_includes}, "${python_libs} -lpython2.4")
+ fi
+ fi
+ if test "${have_libpython}" = python2.6; then
+ AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
+ elif test "${have_libpython}" = python2.5; then
+ AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
+ elif test "${have_libpython}" = python2.4; then
+ AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
fi
- if test ${have_libpython} = no; then
+
+ if test "${have_libpython}" = no; then
case "${with_python}" in
yes)
AC_MSG_ERROR([python is missing or unusable])
@@ -667,12 +727,10 @@ else
AC_MSG_ERROR([no usable python found at ${with_python}])
;;
esac
- CPPFLAGS=$save_CPPFLAGS
- LIBS=$save_LIBS
fi
fi

-if test "${have_libpython}" = yes; then
+if test "${have_libpython}" != no; then
AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"