[PATCH] gdb/testsuite: add test for memory requirements of gcore

[Guinevere Larsen <guinevere@redhat.com>]

For a long time, Fedora has been carrying an out-of-tree patch with a
similar test to the one proposed in this patch, that ensures that the
memory requirements don't grow with the inferior's memory. It's been
so long that the context for why this test exists has been lost, but
it looked like it could be interesting for upstream.

The test runs twice, once with the inferior allocating 4Mb of memory,
and the other allocating 64Mb. My plan was to find the rate at which
things increase based on inferior size, and have that tested to ensure
we're not growing that requirement accidentally, but my testing
actually showed memory requirements going down as the inferior increases,
so instead I just hardcoded that we need less than 2Mb for the command,
and it can be tweaked later if necessary.
---
 gdb/testsuite/gdb.base/gcore-memory-usage.c   | 37 +++++++
 gdb/testsuite/gdb.base/gcore-memory-usage.exp | 97 +++++++++++++++++++
 2 files changed, 134 insertions(+)
 create mode 100644 gdb/testsuite/gdb.base/gcore-memory-usage.c
 create mode 100644 gdb/testsuite/gdb.base/gcore-memory-usage.exp

diff --git a/gdb/testsuite/gdb.base/gcore-memory-usage.c b/gdb/testsuite/gdb.base/gcore-memory-usage.c
new file mode 100644
index 00000000000..514fdb905cf
--- /dev/null
+++ b/gdb/testsuite/gdb.base/gcore-memory-usage.c
@@ -0,0 +1,37 @@
+/* This testcase is part of GDB, the GNU debugger.
+
+   Copyright 2025 Free Software Foundation, Inc.
+
+   This program is free software; you can redistribute it and/or modify
+   it under the terms of the GNU General Public License as published by
+   the Free Software Foundation; either version 3 of the License, or
+   (at your option) any later version.
+
+   This program is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+   GNU General Public License for more details.
+
+   You should have received a copy of the GNU General Public License
+   along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
+
+
+#include <stdio.h>
+#include <stdlib.h>
+#include <unistd.h>
+
+int main(int argc, char **argv)
+{
+  /* Use argv to calculate how many megabytes to allocate.
+     Do this to see how much gcore memory usage increases
+     based on inferior dynamic memory.  */
+  int megs = atoi (argv[1]);
+  char *p = malloc (megs * 1024 * 1024);
+
+  /* Wait a long time so GDB can attach to this.  */
+  sleep (10);
+
+  /* Let's be nice citizens :).  */
+  free (p);
+  return 0;
+}
diff --git a/gdb/testsuite/gdb.base/gcore-memory-usage.exp b/gdb/testsuite/gdb.base/gcore-memory-usage.exp
new file mode 100644
index 00000000000..cdb6d73c11b
--- /dev/null
+++ b/gdb/testsuite/gdb.base/gcore-memory-usage.exp
@@ -0,0 +1,97 @@
+# Copyright (C) 2025 Free Software Foundation, Inc.
+
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 3 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, see <http://www.gnu.org/licenses/>.
+
+# Test that gcore doesn't end up using excessive memory.
+
+require {istarget "*-*-linux*"}
+
+standard_testfile
+
+if {[build_executable "failed to prepare" $testfile $srcfile {debug}] == -1} {
+    return -1
+}
+
+# Read the proc_pid_status page, to find how much memory the given
+# PID is using.  This is meant to be used to find the
+# memory usage for the GDB in this test.
+# Returns memory usage in Kb, or -1 if it couldn't be found.
+proc get_mem_usage {pid prefix} {
+    set fd [open "/proc/$pid/status"]
+    set memory -1
+    while {[gets $fd line] != -1} {
+	if {[regexp {VmSize:\s*([0-9]+) kB} $line full mem]} {
+	    set memory $mem
+	    break
+	}
+    }
+    close $fd
+
+    gdb_assert {$memory != -1} "$prefix: Managed to read the memory usage"
+
+    return $memory
+}
+
+# This proc restarts GDB, runs the inferior with the desired
+# amount of memory, then checks how much memory is necessary
+# to run the gcore command.  It will return -1 if the gcore
+# command fails, 0 otherwise.
+proc run_test {megs} {
+    with_test_prefix "$megs Mb" {
+	clean_restart $::testfile
+
+	set bin [standard_output_file $::testfile]
+	set corefile [standard_output_file "${::testfile}.core"]
+	set inferior_pid [eval exec $bin $megs &]
+	set gdb_pid [exp_pid -i [board_info host fileid]]
+
+	# wait for memory allocation to finish.
+	sleep 1
+
+	# Get the important info.
+	gdb_test "attach $inferior_pid" "Attaching to.*"
+	set mem_before [get_mem_usage $gdb_pid before]
+	if {![gdb_gcore_cmd $corefile "create the corefile"]} {
+	    return -1
+	}
+	set mem_after [get_mem_usage $gdb_pid after]
+
+	# Do the main part of the test: How much is the memory
+	# usage of GDB going to grow after using the gcore command.
+	set diff_k [expr $mem_after - $mem_before]
+	set diff [expr $diff_k/1024]
+	verbose -log "The gcore command used $diff Mb ($diff_k Kb)"
+	# The original plan was to compare to a multiple of MEGS
+	# but since the requirements don't seem to go up as the
+	# inferior allocated more memory, we instead just hardcode
+	# 2 megs, since sometimes 1 is used.
+	gdb_assert {$diff < 2} \
+	    "gdb did not use as much memory as the inferior"
+
+	# Kill the inferior so we don't have to wait until the process
+	# finishes.
+	gdb_test "signal SIGKILL" ".*The program no longer exists."
+    }
+    return 0
+}
+
+# If we couldn't create the first corefile, there's no point
+# in running the second part of the test.
+if {[run_test 4] != 0} {
+    return
+}
+# Surprisingly enough, the larger inferior doesn't seem to use
+# any extra memory, it usually uses less memory.  Which is good,
+# it means our memory requirements aren't growing with the inferior.
+run_test 64
-- 
2.48.1