[PATCH v4 9/9] gdb/testsuite: add inferior arguments test

Michael Weghorn
2020-05-13T09:48:28Z

From: Simon Marchi <simon.marchi@efficios.com>

Add a test for verifying different methods of passing arguments to the
inferior: the start, starti and run commands, as well as `set args`.

All these methods work naturally when using the unix or
native-extended-gdbserver target boards. Since those are non-stub
boards, GDB runs new inferiors and therefore pass arguments to them.
With target boards where GDB connects to a stub, for example with
native-gdbserver, they don't really make sense. The inferior process is
already started when GDB connects.

However, the "run" method is still tested with stub targets, because the
gdb_run_cmd procedure is adapted for stub targets. Instead of issuing
the `run` command, it spawns whatever program is supposed to bring up
the stub (gdbserver, for example) using gdb_reload and makes GDB connect
to it. So this allows us to exercise argument passing through the
gdbserver command line, when testing with the native-gdbserver board.

Note that there is already a gdb.base/args.exp, but this tests
specifically the --args switch of GDB. Perhaps it could be integrated
in this new test, as a new "method".

gdb/testsuite/ChangeLog:

* lib/gdb.exp (gdb_run_cmd): Return success or failure.
* gdb.base/inferior-args.exp: New file.
* gdb.base/inferior-args.c: New file.
---
gdb/testsuite/gdb.base/inferior-args.c | 8 ++
gdb/testsuite/gdb.base/inferior-args.exp | 126 +++++++++++++++++++++++
gdb/testsuite/lib/gdb.exp | 21 ++--
3 files changed, 147 insertions(+), 8 deletions(-)
create mode 100644 gdb/testsuite/gdb.base/inferior-args.c
create mode 100644 gdb/testsuite/gdb.base/inferior-args.exp

diff --git a/gdb/testsuite/gdb.base/inferior-args.c b/gdb/testsuite/gdb.base/inferior-args.c
new file mode 100644
index 0000000000..74ca58b508
--- /dev/null
+++ b/gdb/testsuite/gdb.base/inferior-args.c
@@ -0,0 +1,8 @@
+#include <stdio.h>
+
+int main(int argc, char **argv) {
+ for (int i = 0; i < argc; i++)
+ printf("[%d] %s\n", i, argv[i]);
+
+ return 0;
+}
diff --git a/gdb/testsuite/gdb.base/inferior-args.exp b/gdb/testsuite/gdb.base/inferior-args.exp
new file mode 100644
index 0000000000..dcda102fe5
--- /dev/null
+++ b/gdb/testsuite/gdb.base/inferior-args.exp
@@ -0,0 +1,126 @@
+# Copyright 2020 Free Software Foundation, Inc.
+
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 3 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program. If not, see <http://www.gnu.org/licenses/>.
+
+# Test running an inferior with arguments.
+
+# This does not work on boards that don't support inferior arguments.
+if [target_info exists noargs] then {
+ verbose "skipping gdb.base/inferior-args.exp because of noargs"
+ return
+}
+
+standard_testfile .c
+
+if {[build_executable "failed to prepare" $testfile $srcfile debug] == -1} {
+ return
+}
+
+clean_restart $binfile
+
+proc do_test { method } {
+ global binfile hex
+
+ # The second arg is an empty string on purpose.
+ set inferior_args { "first arg" "" "third-arg" }
+
+ clean_restart $binfile
+
+ if { $method == "start" } {
+ # The start command does not make sense for a stub.
+ if { [use_gdb_stub] } {
+ return;
+ }
+
+ if { [gdb_start_cmd $inferior_args] < 0 } {
+ fail "could not issue start command"
+ return -1
+ }
+
+ # Consume up to the GDB prompt after the stop.
+ gdb_test "" ".*main.*" "stop at main"
+
+ } elseif { $method == "starti" } {
+ # The starti command does not make sense for a stub.
+ if { [use_gdb_stub] } {
+ return;
+ }
+
+ if { [gdb_starti_cmd $inferior_args] < 0 } {
+ fail "could not issue start command"
+ return -1
+ }
+
+ # Consume up to the GDB prompt after the stop.
+ gdb_test "" "" "stop at first instruction"
+
+ # Put a breakpoint and continue until main.
+ if { ![gdb_breakpoint "main" message] } {
+ fail "could not set breakpoint on main"
+ return -1
+ }
+
+ if { [gdb_continue "main"] != 0 } {
+ fail "could not continue to main"
+ return -1
+ }
+
+ } elseif { $method == "run" } {
+ if { ![gdb_breakpoint "main" message] } {
+ fail "could not set breakpoint on main"
+ return -1
+ }
+
+ # The run command does not make sense for a stub, but GDB_RUN_CMD
+ # does the right thing when the target is a stub (start the stub,
+ # connect to it, and "continue").
+ #
+ # This allows us to test arguments passed on the gdbserver command
+ # line.
+ if { [gdb_run_cmd $inferior_args] < 0 } {
+ fail "could not run"
+ return -1
+ }
+
+ # Consume up to the GDB prompt after the stop.
+ gdb_test "" ".*main.*" "stop at main"
+
+ } elseif { $method == "set args" } {
+ # Using "set args" does not make sense with a stub.
+ if { [use_gdb_stub] } {
+ return;
+ }
+
+ gdb_test_no_output "set args $inferior_args"
+
+ if { ![runto_main] } {
+ fail "could not run to main"
+ return -1
+ }
+
+ } else {
+ error "invalid method $method"
+ }
+
+ # Now that we are stopped at main, inspect argc/argv.
+ gdb_test "print argc" " = 4"
+ gdb_test "print argv\[0\]" " = $hex \".*\""
+ gdb_test "print argv\[1\]" " = $hex \"first arg\""
+ gdb_test "print argv\[2\]" " = $hex \"\""
+ gdb_test "print argv\[3\]" " = $hex \"third-arg\""
+}
+
+foreach_with_prefix method { "start" "starti" "run" "set args" } {
+ do_test $method
+}
diff --git a/gdb/testsuite/lib/gdb.exp b/gdb/testsuite/lib/gdb.exp
index ec77cfb0d3..a5eeba6b3c 100644
--- a/gdb/testsuite/lib/gdb.exp
+++ b/gdb/testsuite/lib/gdb.exp
@@ -241,6 +241,8 @@ proc target_can_use_run_cmd {} {

# Generic run command.
#
+# Return 0 if we could start the program, -1 if we could not.
+#
# The second pattern below matches up to the first newline *only*.
# Using ``.*$'' could swallow up output that we attempt to match
# elsewhere.
@@ -268,14 +270,14 @@ proc gdb_run_cmd { {inferior_args {}} } {
if $use_gdb_stub {
if [target_info exists gdb,do_reload_on_run] {
if { [gdb_reload $inferior_args] != 0 } {
- return
+ return -1
}
send_gdb "continue\n"
gdb_expect 60 {
-re "Continu\[^\r\n\]*\[\r\n\]" {}
default {}
}
- return
+ return 0
}

if [target_info exists gdb,start_symbol] {
@@ -291,7 +293,7 @@ proc gdb_run_cmd { {inferior_args {}} } {
# clever and not send a command when it has failed.
if [expr $start_attempt > 3] {
perror "Jump to start() failed (retry count exceeded)"
- return
+ return -1
}
set start_attempt [expr $start_attempt + 1]
gdb_expect 30 {
@@ -300,7 +302,7 @@ proc gdb_run_cmd { {inferior_args {}} } {
}
-re "No symbol \"_start\" in current.*$gdb_prompt $" {
perror "Can't find start symbol to run in gdb_run"
- return
+ return -1
}
-re "No symbol \"start\" in current.*$gdb_prompt $" {
send_gdb "jump *_start\n"
@@ -313,22 +315,23 @@ proc gdb_run_cmd { {inferior_args {}} } {
}
-re "The program is not being run.*$gdb_prompt $" {
if { [gdb_reload $inferior_args] != 0 } {
- return
+ return -1
}
send_gdb "jump *$start\n"
}
timeout {
perror "Jump to start() failed (timeout)"
- return
+ return -1
}
}
}
- return
+
+ return 0
}

if [target_info exists gdb,do_reload_on_run] {
if { [gdb_reload $inferior_args] != 0 } {
- return
+ return -1
}
}
send_gdb "run $inferior_args\n"
@@ -345,6 +348,8 @@ proc gdb_run_cmd { {inferior_args {}} } {
# There is no more input expected.
}
}
+
+ return 0
}

# Generic start command. Return 0 if we could start the program, -1
--
2.26.2